PWMの理解ーーその２：ブザーで音楽

■周波数

PWMとは、Pulse Width Modulationの略で、波長のような制御を行います。

細かい部分で見ると、ONとOFFを一定間隔で繰り返しているだけです。

ここで周波数といった名前が登場しますが、ONの長さの事を指します。

ブザーにとっての周波数とは、ドレミの音階を指定することができることになります。

ESP32では、PWM制御の関数が用意されております。（ledcSetup、ledcAttachPin、ledcWriteTone）

■音階

音階は、「音を高低の順番に並べたもの」あり、音の高低は周波数で表します。

音は、周波数が半分になると１オクターブ低くなり、周波数が倍になると１オクターブ高くなります。

１オクターブには１２の音があり（①ド、②ド＃（レ♭）、③レ、④レ＃（ミ♭）、⑤ミ、⑥ファ、⑦ファ＃（ソ♭）、⑧ソ、⑨ソ＃（ラ♭）、⑩ラ、⑪ラ＃（シ♭）、⑫シ）、

その１２の音は、隣り合う半音間での周波数の比率が同じです。（音階に対して等比数列的に増える）

音階と周波数の関係は下記サイトをご参照ください。

音階の周波数

■配線図

■プログラム

#define BUZZER_PIN 2              // ブザーのピン番号

#define BUZZER_CHANEL 0       // ブザーのチャネル番号

#define BEAT 250                 　 // 音の長さ（0.25秒間隔）

#define G3 196 // ソ3

#define C4 261.6 // ド4       1

#define D4 293.665 // レ4     2

#define E4 329.63 // ミ4      3

#define F4 349.228 // ファ4   4

#define G4 391.995 // ソ4     5

#define A4 440 // ラ4         6

#define B4 493.883 // シ4     7

#define C5 523.251 // ド5     i

void playTone(double tone, int num) {

  ledcWriteTone(BUZZER_CHANEL, tone);

  delay(BEAT * num);

}

void playTone(long tone) {

  playTone(tone, 2);

}

void playMusic() {

  // 1 2 3 1 | 1 2 3 1 | 3 4 5 - | 3 4 5 - |

  // 56543 1 | 56543 1 | 3 5 1 - | 3 5 1 -

  playTone(C4);

  playTone(D4);

  playTone(E4);

  playTone(C4);

  playTone(C4);

  playTone(D4);

  playTone(E4);

  playTone(C4);

  playTone(E4);

  playTone(F4);

  playTone(G4, 4);

  playTone(E4);

  playTone(F4);

  playTone(G4, 4);

  playTone(G4, 1);

  playTone(A4, 1);

  playTone(G4, 1);

  playTone(F4, 1);

  playTone(E4);

  playTone(C4);

  playTone(G4, 1);

  playTone(A4, 1);

  playTone(G4, 1);

  playTone(F4, 1);

  playTone(E4);

  playTone(C4);

  playTone(E4);

  playTone(G3);

  playTone(C4, 4);

  playTone(E4);

  playTone(G3);

  playTone(C4, 4);

}

void setup() {

  ledcSetup(BUZZER_CHANEL, 12000, 8);

  ledcAttachPin(BUZZER_PIN, BUZZER_CHANEL);

}

void loop() {

  playMusic();

  delay(1000);

}

ESP32-C3開発ボードに書き込みできない解決方法

 ■問題

ARDUINO環境で、ESP32-C3の開発ボードに書き込み時、下記エラーが出てます。

A fatal error occurred: Invalid head of packet (0x47)

■原因

新発行のESP32-C3開発ボードに対して、ARDUINOはまたサポートしておりません。

解決方法としては最新のLIBをインストールする

■インストール手順：

・最新版ARDUINOをダウンロード＆インストールする

https://www.arduino.cc/en/software

・最新のESP32LIBを切り替える

https://github.com/espressif/arduino-esp32から、ESP32をZIPでダウンロードする

・C:\Users\XXXXXXXXXX\ArduinoData\packages\esp32\hardware\esp32\1.0.6

に解凍する

解凍後はこのイメージです

・tools\get.exeを実施する

・ARDUINOを再起動し、ESP-C3の選択肢が見つかれます。

・「ESP32C3 Dev Module」を選択し、正常書き込みできました。

PWMの理解ーーその１：雰囲気ランプ

■ESP32-C3開発ボード

 ESP32-C3はLEDコントローラーが持っています。これを使って、簡単に雰囲気ランプ効果ができます。

今回は、ESP-C3-32開発ボードを利用します。下記ようなものです。

赤枠で、開発ボードで一つRGB LEDがあります。次は、このRGB LEDをコントロールしてみます。

■GPIO情報

上図をみると、IO3、IO4、IO5のいずれもRGB LEDを繋がっています（それぞれはR、G、Ｂです）から、サンプルとして、今回はIO3（赤色）を利用しましょう。

■PWMコントロール

PWMとは、Pulse Width Modulationの略で、波長のような制御を行います。

PWMをコントロールするために、下記設定が必要です：

１、タイマーを配置： のDuty比率を指定する

２、チャネルを配置：PWMデータ出力のGPIO

３、ハードウェアのFadeOn機能を利用し、LEDの明るさを変更する

楽鑫は相応の構造体を提供しました。提供している構造体を利用してやりやすいです。

ledc_timer_config_t　　⇒ タイマー配置用

ledc_channel_config_t　⇒ チャネル配置用

■プログラム

ledcはESP32のLED用高精度PWM機能です。通常のPWMだけでなく、ledc_set_fade_with_timeとledc_fade_startを使えば自動的に指定秒数でfadeしてくれて大変便利。

#include <stdio.h>

#include "freertos/FreeRTOS.h"

#include "freertos/task.h"

#include "driver/gpio.h"

#include "driver/ledc.h"

#include "sdkconfig.h"

#include "driver/ledc.h"

#define BLINK_GPIO_R 3

#define BLINK_GPIO_G 4

#define BLINK_GPIO_B 5

#define LEDC_TEST_DUTY 1000

#define LEDC_TEST_FADE_TIME 2000

ledc_timer_config_t   ledc_timer;

ledc_channel_config_t ledc_channel;

void setup() {

  ledc_timer.duty_resolution = LEDC_TIMER_10_BIT; // PWM Duty

  ledc_timer.freq_hz = 1000; // PWM信号の周波数

  ledc_timer.speed_mode = LEDC_LOW_SPEED_MODE; // タイマーモード(低速)

  ledc_timer.timer_num = LEDC_TIMER_0; // タイマー インデックス

  ledc_timer_config(&ledc_timer);

  ledc_channel.channel = LEDC_CHANNEL_0;

  ledc_channel.duty = 0;

  ledc_channel.gpio_num = BLINK_GPIO_R;

  ledc_channel.speed_mode = LEDC_LOW_SPEED_MODE;

  ledc_channel.timer_sel = LEDC_TIMER_0;

  ledc_channel_config(&ledc_channel);

  

  ledc_fade_func_install(0);

}

void loop() {

  ledc_set_fade_with_time(ledc_channel.speed_mode, ledc_channel.channel, LEDC_TEST_DUTY, LEDC_TEST_FADE_TIME);

  ledc_fade_start(ledc_channel.speed_mode, ledc_channel.channel, LEDC_FADE_NO_WAIT);

  vTaskDelay(LEDC_TEST_FADE_TIME / portTICK_PERIOD_MS);

  ledc_set_fade_with_time(ledc_channel.speed_mode, ledc_channel.channel, 0, LEDC_TEST_FADE_TIME);

  ledc_fade_start(ledc_channel.speed_mode, ledc_channel.channel, LEDC_FADE_NO_WAIT);

  vTaskDelay(LEDC_TEST_FADE_TIME / portTICK_PERIOD_MS);

}

■最終結果

 ■RGBを同時コントロールの場合、構造体はこのような実装する

  ledc_channel_config_t ledc_channel[3];

  ledc_channel[0].channel = LEDC_CHANNEL_0;

  ledc_channel[0].duty = 0;

  ledc_channel[0].gpio_num = BLINK_GPIO_R;

  ledc_channel[0].speed_mode = LEDC_LOW_SPEED_MODE;

  ledc_channel[0].timer_sel = LEDC_TIMER_0;

  ledc_channel[1].channel = LEDC_CHANNEL_1;

  ledc_channel[1].duty = 0;

  ledc_channel[1].gpio_num = BLINK_GPIO_G;

  ledc_channel[1].speed_mode = LEDC_LOW_SPEED_MODE;

  ledc_channel[1].timer_sel = LEDC_TIMER_1;

  ledc_channel[2].channel = LEDC_CHANNEL_2;

  ledc_channel[2].duty = 0;

  ledc_channel[2].gpio_num = BLINK_GPIO_B;

  ledc_channel[2].speed_mode = LEDC_LOW_SPEED_MODE;

  ledc_channel[2].timer_sel = LEDC_TIMER_2;

  ledc_channel_config(&ledc_channel[0]);

  ledc_channel_config(&ledc_channel[1]);

  ledc_channel_config(&ledc_channel[2]);

MQTTプロトコル紹介

 ■MQTTとは

　MQTT（Message Queue Telemetry Transport）は、発行/購読型のメッセージ処理を実現するための軽量なプロトコルとして設計されています。

　メッセージのサブスクライバー（購読者）は、メッセージのパブリッシャー（発行元）が提供する MQTT トピックをあらかじめ講読しておきます。MQTT トピックに何か変化があると、サブスクライバーは PUBLISH コマンドを受け取ってそれを知ることができます。

　ネットワークが不安定な場所や、性能が低いデバイスでも動くように軽量化されているのが特徴で、TCP/IP ネットワークをベースに作られています。

■HTTPとMQTTの比較

HTTP	MQTT
同期/非同期	同期	非同期
送受信対象	1対1	多対多
データ量	大きい（重い）	小さい（軽い）
通信が不安定	×（送受信不可）	○（再送受信可能）

■MQTTの特徴

・シンプル

・軽量

・省エネ

■MQTTバージョン

　メインバージョンはMQTT3.1.1とMQTT5の二つがあります。

　MQTT3.1.1は2014年10月発行

　MQTT5は2019年3月発行

■MQTTトピック

　MQTT プロトコルでは、メッセージの講読や発行の対象として MQTT トピックを使用します。

　プロトコル上、MQTT トピックはパブリッシャーに複数存在し、それらは階層を持ったトピック名として表現されます。サブスクライバーは MQTT のトピック名を指定してそのトピックを講読したり、メッセージを発行したりできます。

　使用例

　MQTTプロトコルはIoTの重要なプロトコルですが、後続でMQTTサーバーの構築とスマートフォンAPPサンプルはまた紹介します。

WebSocketでOV7670-ESP32の画像表示

 ■OV7670

　OV7670 はVGA（640×480画素）サイズのイメージセンサです。内部構造はCMOSイメージセンサと信号処理用 DSPがワンチップになっています。マイコンへの映 像信号出力は、ディジタル8ビット・パラレルです。

製品仕様：

・イメージセンサー：ＯＶ７６７０　ＣＭＯＳ、ＶＧＡ－６４０（Ｖ）×４８０（Ｖ）

・レンズ焦点距離：3.6mm（F2.5）

・光学サイズ：1/6型、画素セル：3.6um x 3.6um

・フィールド角：25°（対角）

・小さいサイズ：3.5cm x 3.5cm

・低動作電圧：２．５V～３．０ＶＤＣ

・低動作電流：60mw(15fps VGA YUV format)

・スリープモード＜20μA

・保存温度：-30℃～70℃

・動作温度：0℃～50℃

・感度：1.3V/(Lux-sec)

・インターフェース：標準SCCB(Serial Camera Control Bus)インターフェース(I2C互換)

・データ出力フォーマット：Raw RGB、RGB(GRB4:2:2)、RGB(565/555/444)、YUV(4:2:2)、YCbCr(4:2:2)

・データ出力解像度:VGA、CIF、CIF～40x30の任意解像度

・サンプリングタイプ:Vario Pixel

・接続コネクタ:2.54mmピッチ(2列)18ピン、ピンヘッダ

■ESP32接続

　下記ように、OV7670のピンとESP32ピンを接続します。

　※データ転送スピードを考えると、短いジャンプワイヤーが勧め

　※SDAとSCLは1KΩの抵抗を使用でも可

OV7670	ESP32
D0	IO36
D1	IO39
D2	IO34
D3	IO35
D4	IO32
D5	IO33
D6	IO25
D7	IO26
MCLK	IO15
PCLK	IO14
HREF	IO23
VSYNC	IO13
SDA	IO21 (1kΩ Pull Up)
SCL	IO22 (1KΩ Pull Up)
RST	3.3V
PWDN	GND

■Web送信

　Web送信はWebSocketを使いました。

　下記ライブラリが必要です。

■部品一覧：

・ESP-WROOM-32開発ボード

・OV7670

・USBケーブル

・ジャンプワイヤー

・1KΩ抵抗*2

・ブレッドボード

■プログラム：

　単純なESP32、OV7670と接続ため（FIFOなどがない）、インターネットのいろいろなサンプルを試した結果で、

　ESP32-OV7670-WebSocket-Camera

は使えます。

　

　下記箇所をちょっと修正しました。

　①13行目～14行目までのWiFi接続情報

　②23行目～33行目までのピン情報

　③APモードは不要のため、削除

　④DBABuffer.hはコンパイルエラーあるため、「#include <stdlib.h>」を追加

#include "OV7670.h"

#include <WebSockets.h>

#include <WebSocketsClient.h>

#include <WebSocketsServer.h>

#include <WiFi.h>

#include <WiFiMulti.h>

#include <WiFiClient.h>

#include "canvas_htm.h"

const char *ssid_AP_1 = "XXXXXX";

const char *pwd_AP_1  = "XXXXXXX";

const int SIOD = 21; //SDA

const int SIOC = 22; //SCL

const int VSYNC = 13;

const int HREF = 23;

const int XCLK = 15;

const int PCLK = 14;

const int D0 = 36;

const int D1 = 39;

const int D2 = 34;

const int D3 = 35;

const int D4 = 32;

const int D5 = 33;

const int D6 = 25;

const int D7 = 26;

const int TFT_DC = 2;

const int TFT_CS = 5;

OV7670 *camera;

WiFiMulti wifiMulti;

WiFiServer server(80);

unsigned char pix = 0;

unsigned char start_flag = 0xAA;

unsigned char end_flag = 0xFF;

unsigned char ip_flag = 0x11;

WebSocketsServer webSocket(81);    // create a websocket server on port 81

void startWebSocket() { // Start a WebSocket server

  webSocket.begin();                          // start the websocket server

  webSocket.onEvent(webSocketEvent);          // if there's an incomming websocket message, go to function 'webSocketEvent'

  Serial.println("WebSocket server started.");

}

void startWebServer()

{

   server.begin();

   Serial.println("Http web server started.");

}

void serve() {

  WiFiClient client = server.available();

  if (client) 

  {

    //Serial.println("New Client.");

    String currentLine = "";

    while (client.connected()) 

    {

      if (client.available()) 

      {

        char c = client.read();

        //Serial.write(c);

        if (c == '\n') 

        {

          if (currentLine.length() == 0) 

          {

            client.println("HTTP/1.1 200 OK");

            client.println("Content-type:text/html");

            client.println();

            client.print(canvas_htm);

            client.println();

            break;

          } 

          else 

          {

            currentLine = "";

          }

        } 

        else if (c != '\r') 

        {

          currentLine += c;

        }

        

      }

    }

    // close the connection:

    client.stop();

  }  

}

void webSocketEvent(uint8_t num, WStype_t type, uint8_t * payload, size_t payloadlength) { // When a WebSocket message is received

 

  int blk_count = 0;

  char canvas_VGA[] = "canvas-VGA";

  char canvas_Q_VGA[] = "canvas-Q-VGA";

  char canvas_QQ_VGA[] = "canvas-QQ-VGA";

  char canvas_QQQ_VGA[] = "canvas-QQQ-VGA";

  char ipaddr[26] ;

  IPAddress localip;

  

  switch (type) {

    case WStype_DISCONNECTED:             // if the websocket is disconnected

      Serial.printf("[%u] Disconnected!\n", num);

      break;

    case WStype_CONNECTED: {              // if a new websocket connection is established

        IPAddress ip = webSocket.remoteIP(num);

        Serial.printf("[%u] Connected from %d.%d.%d.%d url: %s\n", num, ip[0], ip[1], ip[2], ip[3], payload);

           webSocket.sendBIN(0, &ip_flag, 1);

           localip = WiFi.localIP();

           sprintf(ipaddr, "%d.%d.%d.%d", localip[0], localip[1], localip[2], localip[3]);

           webSocket.sendTXT(0, (const char *)ipaddr);

           

      }

      break;

    case WStype_TEXT:                     // if new text data is received

      if (payloadlength == sizeof(canvas_QQQ_VGA)-1) {

        if (memcmp(canvas_QQQ_VGA, payload, payloadlength) == 0) {

              Serial.printf("canvas_QQQ_VGA");

              webSocket.sendBIN(0, &end_flag, 1);

              camera = new OV7670(OV7670::Mode::QQQVGA_RGB565, SIOD, SIOC, VSYNC, HREF, XCLK, PCLK, D0, D1, D2, D3, D4, D5, D6, D7);

        }

      } else if (payloadlength == sizeof(canvas_QQ_VGA)-1) {

        if (memcmp(canvas_QQ_VGA, payload, payloadlength) == 0) {

              Serial.printf("canvas_QQ_VGA");

              webSocket.sendBIN(0, &end_flag, 1);

              camera = new OV7670(OV7670::Mode::QQVGA_RGB565, SIOD, SIOC, VSYNC, HREF, XCLK, PCLK, D0, D1, D2, D3, D4, D5, D6, D7);

        }

      } else if (payloadlength == sizeof(canvas_Q_VGA)-1) {

        if (memcmp(canvas_Q_VGA, payload, payloadlength) == 0) {

              Serial.printf("canvas_Q_VGA");

              webSocket.sendBIN(0, &end_flag, 1);

              camera = new OV7670(OV7670::Mode::QVGA_RGB565, SIOD, SIOC, VSYNC, HREF, XCLK, PCLK, D0, D1, D2, D3, D4, D5, D6, D7);

        }

      } else if (payloadlength == sizeof(canvas_VGA)-1) {

        if (memcmp(canvas_VGA, payload, payloadlength) == 0) {

              Serial.printf("canvas_VGA");

              webSocket.sendBIN(0, &end_flag, 1);

              camera = new OV7670(OV7670::Mode::VGA_RGB565, SIOD, SIOC, VSYNC, HREF, XCLK, PCLK, D0, D1, D2, D3, D4, D5, D6, D7);

        }

      } 

      

      blk_count = camera->yres/I2SCamera::blockSlice;//30, 60, 120

      for (int i=0; i<blk_count; i++) {

          if (i == 0) {

              camera->startBlock = 1;

              camera->endBlock = I2SCamera::blockSlice;

              webSocket.sendBIN(0, &start_flag, 1);

          }

          if (i == blk_count-1) {

              webSocket.sendBIN(0, &end_flag, 1);

          }

        

          camera->oneFrame();

          webSocket.sendBIN(0, camera->frame, camera->xres * I2SCamera::blockSlice * 2);

          camera->startBlock += I2SCamera::blockSlice;

          camera->endBlock   += I2SCamera::blockSlice;

      }

      

      break;

    case WStype_ERROR:                     // if new text data is received

      Serial.printf("Error \n");

    default:

      Serial.printf("WStype %x not handled \n", type);

  }

}

void initWifiMulti()

{

    wifiMulti.addAP(ssid_AP_1, pwd_AP_1);

    Serial.println("Connecting Wifi...");

    while(wifiMulti.run() != WL_CONNECTED) {

       delay(5000);        

       Serial.print(".");

    }

    

    Serial.print("\n");

    Serial.print("WiFi connected : ");

    Serial.print("IP address : ");

    Serial.println(WiFi.localIP());

}

void setup() {

  Serial.begin(115200);

  initWifiMulti();

  startWebSocket();

  startWebServer();

}

void loop()

{

  webSocket.loop();

  serve();

}

■結果

ブラウザーを開いて、URLを入力し

配線イメージ

写真工場　：）

リードスイッチ形磁気形近接センサー、静電容量方式タッチセンサー、アクティブブザーモジュールの連動

■リードスイッチ形磁気形近接センサー

　リードスイッチは下図のように2枚のニッケル合金（磁性体）リードの一部をオーバーラップさせ、ガラス管に封入したもので、 このオーバーラップ部分は表面に金、銀及びロジウムなどの接点処理が施されており、さらに接点の活性化を防ぐためにガラス管内に不活性ガスを封入している。

　リードスイッチに電磁コイルまたは磁石によって磁界が作用するとリードが磁化され、磁界の２乗に比例したオーバーラップ部分の吸引力Fpが生じる。

　この吸引力でリードがたわむと、リード自体の弾性により反発力Fsが生じる。

　すなわち、Fp＞Fsであるような磁界において接点は閉成される。

　また、Fp＜Fsとなるような磁界において接点は開放される。

　磁気形近接スイッチでは、このようなリードスイッチの動作機構を利用し、磁石との組合せにおいて各種の機能を得ている。

■静電容量方式タッチセンサー

　「タッチセンサー」の表面に指で触れると生じる静電容量（電荷）の変化を、「センサー」が感知することで位置を認識します。

　「静電容量」とは、電気を蓄える能力であり、人体など、電気を通すものが近づいただけで変化します。

　電気を蓄えられる時間の変化から「静電容量」の増減を調べられるので、人体の接近を検知することが出来ます。

　この「センサー」は、指と「センサー」の間に遮蔽物があっても機能します。

■アクティブブザーモジュール

　電気を流すだけでピーと音が鳴ります。digitalWrite() で ON/OFF して制御します。

■磁気検知機

　磁気検知機が作成られると思って、下記機能を想定されています。

　磁石を近くにより、磁気を感知され、アクティブブザーを発音します。タッチセンサーにタッチして、消音します。

　見やすいために、赤LEDを追加し、アクティブブザーを発音／消音に従って、点灯／消灯します。

■配線図

※実物のアクティブブザーモジュールの「＋」「S」ピンは間違いました。

　正しい順番は「-」「+」「S」

■プログラム：

#define BUZZER 4  // D2
#define TOUCH_PIN 5  // D1
#define REED 2  // D4
#define LED_PIN 16  // D0
void setup() {
  Serial.begin(115200);
  pinMode(BUZZER, OUTPUT);
  pinMode(LED_PIN, OUTPUT);
  pinMode(TOUCH_PIN, INPUT);
  pinMode(REED, INPUT);
  digitalWrite(BUZZER, LOW);
  digitalWrite(LED_PIN, LOW);
}
void loop() {
  int val = digitalRead(REED);
  Serial.print("val=");
  Serial.println(val);
  if (val == LOW) {
    // 磁気近くになる時
    Serial.println("Scanned!");
    digitalWrite(BUZZER, HIGH);
    digitalWrite(LED_PIN, HIGH);
  } else {
    // 磁気が遠くになる時
    digitalWrite(BUZZER, LOW);
    digitalWrite(LED_PIN, LOW);
  }
  if (digitalRead(TOUCH_PIN) == HIGH) {
    // タッチの時
    Serial.println("Cleared!");
    digitalWrite(BUZZER, LOW); 
    digitalWrite(LED_PIN, LOW);
  }
  delay(1000);
}

■実物イメージ

磁気近くなる時：

 タッチセンサーにタッチする：

予想通り :)

ESP8266とESP32で、WIFIのWEBサーバ構築

今日はESP8266とESP32のWIFI機能を勉強しましょう。

ESP8266とESP32両方もWIFI機能が付きます。同じWIFIを接続している時、相互でデータ通信ができます。それに、PCや携帯とも通信できます。

今回は下記のようなWIFIネットを作ります。

・ESP8266：WiFiルーターです。ESP32、PC、携帯はすべて該当WiFiにつながる。

・ESP32：Webサーバーです。PC、携帯のブラウザーはこのサーバーへHttpアクセスできる。

■APモード

アクセスポイントモード（AP）はブリッジモードとも呼ばれ、Wi-Fiルーターを無線LANの親機として利用する機能です。 パソコンやスマートフォンなどを無線で接続したい時に切り替えるモードと考えると違いが分かりやすいでしょう。

下記のプログラムで、楽々作れます。

#include <ESP8266WiFi.h>

const char *ssid = "phoenix";  // WIFI名

const char *password = "12345678"; // パスワード

void setup() {

  Serial.begin(115200);

  WiFi.softAP(ssid, password);  // APモード

  Serial.print("Access Point: ");

  Serial.println(ssid);

  Serial.print("IP address: ");

  Serial.println(WiFi.softAPIP());

}

void loop() {

}

 ソースをESP8266にアップロードすると、「phoenix」とのWiFiが見えます。

　※原因はわかりませんが、何回で試して、該当WiFiが見つかれません。結局はあったから、よかった。

ソースでのパスワードを入力して、つながれます。

PCを該当Wifiを接続すると、「Cmd」ウインドウで「Ping」コマンドを検証して、

順調接続しました。

■Webサーバー

WiFiライブラリを利用して、簡単なWebサーバーが構築できます。

プログラムは下記ようになります。

#include <WiFiMulti.h>

WiFiServer server(80);

WiFiClient WSclient;

WiFiMulti wifiMulti;

const char *html = "HTTP/1.1 200 OK\r\n"

  "Content-type:text/html\r\n"

  "Connection:close\r\n"    

  "\r\n"    //１行空行

  "<!DOCTYPE html>\n"

  "<html lang='ja'>\n"

  "<head>\n"

  "<meta charset='UTF-8'>\n"

  "<meta name='viewport' content='width=device-width'>\n"

  "<title>Phoenix-WebServer</title>\n"

  "</head>\n"

  "<body>\n"

  "Hello World!\n"

  "</body>\n"

  "</html>\n";

bool wifi_connect(){

  wifiMulti.addAP("phoenix", "12345678");  // Wifiに接続

  Serial.println(F("Connecting Wifi..."));

  if(wifiMulti.run() == WL_CONNECTED) {

    Serial.println(F("--- WiFi connected ---"));

    Serial.print(F("SSID: "));

    Serial.println( WiFi.SSID() );

    Serial.print(F("IP Address: "));

    Serial.println( WiFi.localIP() );

    Serial.print(F("signal strength (RSSI): "));

    Serial.print( WiFi.RSSI() );    // 信号レベル

    Serial.println(F("dBm"));

    return true;

  } else {

    return false;

  }

}

void printHTML(WiFiClient &client){

    Serial.println("sendHTML ...");

    client.print(html);

    Serial.println("sendHTML Done");    

}

void Ini_HTTP_Response(void){

  String req;

  

  WiFiClient client = server.available();        // サーバーに対して外部から接続があるかどうかを監視

  if(!client) return;  // クライアントからのアクセス要求があり、接続が確立し、読み取りが出来る状態になるとtrue

  while(client.connected()){                    // クライアントが接続状態の間

    if(!client.available()) break;              // 読み取り可能バイトが無いなら終了

    Serial.println(F("----Client Receive----"));    

    req = client.readStringUntil('\n');          // １行読み込み

    if(req.indexOf("GET / HTTP") != -1){        // ブラウザからリクエストを受信したらこの文字列を検知する

      while(req.indexOf("\r") != 0){   // ブラウザからのリクエストで空行（\r\nが先頭になる）まで読み込む

        req = client.readStringUntil('\n');      // \nまで読み込むが\n自身は文字列に含まれず、捨てられる

        Serial.println(req);

        if(req.indexOf("websocket") != -1){

          Serial.println(F("\nPrint WS HandShake---"));

          return;

        }

      }

      delay(10);                                // 10ms待ってレスポンスをブラウザに送信

      Serial.println(F("\nPrint HTML-----------"));

      printHTML(client);                        // レスポンス(HTML)を返す

      Serial.println(F("\nPrint HTML end-------"));

    } else{                                        // その他のリクエスト（faviconなど）全部読み飛ばす

      Serial.println(F("*** Anather Request ***"));

      Serial.print(req);

      while(client.available()){

        Serial.write(client.read());            // ブラウザからデータが送られている間読み込む

      }

    }

  }

}

void setup() {

  // put your setup code here, to run once:

  Serial.begin(115200);

  if(wifi_connect()){ 

    server.begin();      // クライアントの接続待ち状態にする

  }

}

void loop() {

  // put your main code here, to run repeatedly:

  Ini_HTTP_Response();

}

■検証

まずはPCです。シリアルモニタで出力されたIPアドレスを入力してみます。

出きった！！！

携帯も同じで試します。

OK！！